cd "/Users/dave/UCSF/Projects/Teaching/Teaching 13/Lecture 2"
use "lecture2.dta", clear
set more off

* Slide 3
summ age, detail

graph box age, scheme(s1color) 

recode age min/65=0 65/max=1, gen(over65)
recode age min/80=0 80/max=1, gen(over80)

* Slide 6

logistic died over65
predict p65
logistic died over80
predict p80

* Slide 8

twoway (line p65 age, sort connect(stairstep)) (line p80 age, sort connect(stairstep)), ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend(off)

* Slide 11

xtile age4=age, nq(4)
xi: logistic died i.age4


predict four
* Graph of Quartile Fit -- Not Shown
twoway (line four age, sort connect(stairstep)) , ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend(off)

*
*  Fit by Decade - Not Shown
*

recode age min/60=0 60/70=1 70/80=2 80/90=3 90/max=4, generate(decade)
xi: logistic died i.decade
predict preddecade

*
* Slide 15
* 

logistic died age
predict plinear

*
*  Slide 16
*

lincom 5*age
lincom 10*age

*
* Slide 18
*

twoway (line plinear age, sort ) (line preddecade age, sort connect(stairstep)), ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend( order(1 "Continuous Fit" 2 "Decade Fit"))

*
* Slide 21
* 
gen age2 = age^2
logistic died age age2
predict squared

* 
* Slide 22
* 
twoway (line plinear age, sort ) (line squared age, sort), ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend( order(1 "Linear Fit" 2 "With Squared Fit"))

* 
*  Slide 26
* 
gen lage=log(age)
logistic died lage
predict plage

*
* Slide 27
* 
lincom 0.095*lage

*
*  Slide 29
* 

twoway (line plinear age, sort ) (line plage age, sort), ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend( order(1 "Linear Fit" 2 "Log Fit"))

*
*  Slide 40
*
mkspline cube_age = age, cubic nknots(3) displayknots

*
*  Slide 41
*
logistic died cube_age*
predict p_cube, xb
predict prob_cube, p

/*
mkspline lin_age1 50 lin_age2 60 lin_age3 70 lin_age4 80 lin_age5 90 lin_age6 = age, marginal 
logistic died lin_age*
predict p_lin, xb
*/

logistic died age
predict outlin, xb

*
* Slide 42
*
twoway (line p_cube age, sort ) (line outlin age, sort) , ytitle(Log Odds of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend( order(1 "Linear Fit" 2 "Cubic Spline Fit"))

*
*  Slide 43 --
*
logistic died cube_age1 cube_age2
est store splineresults
logistic died age
lrtest splineresults

*
*  Slide 44
*
logistic died cube_age1 cube_age2
test cube_age2=0

*
*  Slide 47
*

 tab raceeth

*
* Slide 48
*
logistic died cube_age* i.raceeth
*
*  Slide 49
*
gen adjlogodds = _b[_cons] + _b[cube_age1]*cube_age1 + _b[cube_age2]*cube_age2 + _b[1.raceeth]*0.80 + _b[2.raceeth]*0.10 + _b[3.raceeth]*0.02 +  _b[4.raceeth]*0.07
gen adjprob = exp( adjlogodds ) /(1+ exp( adjlogodds ))
*
*  Slide 50
*
twoway (line prob_cube age, sort ) (line adjprob age, sort), ytitle(Probability of Dying by 2002) xtitle(Age (Years) in 1998) scheme(s1color) legend( order(1 "Crude" 2 "Adjusted for Race"))