
Strings, Part 1: Splitting and joining strings, converting to/from numeric variables

String variables are commonly encountered in datasets used for clinical research.  Stata provides a variety of ways to manipulate strings, search them, and convert them into numeric variables.  Searching string variables is covered in the “Strings, Part 2” handout, using the example of searching and categorizing ICD-9 and ICD-10 codes.  In this handout, we cover converting a string into a numeric variable (and vice-versa), as well as splitting and “concatenating” (joining together) string variables. 
Converting numeric variables to string variables
It is sometimes helpful to convert a numeric variable into a string variable.  Let’s look at an example.  In this dataset, ID numbers and subjects’ initials are in two separate variables, but you’d like to put them together and make a single ID variable that includes the initials.  To do this, we’ll first have to convert the idnumber variable into a string variable, and then we can concatenate the two strings together.  

First, let’s change the ID number variable into a non-numeric string variable.  To do this, you use the tostring command in Stata, which converts variables into the most compact string format possible. Here’s a small example dataset:
list idnumber initials

     +---------------------+

     | idnumber   initials |

     |---------------------|

  1. |     2033         ER |

  2. |     2012         MP |

  3. |     3017         MA |

  4. |     1002         TA |

  5. |     3087         MR |

     |---------------------|

  6. |     3069         FT |

  7. |     1028         EA |

     +---------------------+

The following command will tell Stata to take the idnumber variable (a numeric variable), and make a string variable out of it that will be saved as a new variable called idstring.  It is also possible to just have Stata write over the old variable with the new one (use the replace option instead of the generate option, and don’t specify a new variable name), but in general it’s best to generate a new variable and maintain the old one so we can check it.  Here’s the command: 
tostring idnumber, generate(idstring)
Stata tells you that a new string variable, with a maximum length of 4 characters, was created:
idstring generated as str4

We can now manipulate idstring using string functions, like concatenate (or search/categorize them using other special string functions).

Joining two string variables into one string – i.e., concatenation
Now let’s create a new variable id that combines the subjects’ ID numbers with their initials. To do this, we use the concat function. We use the egen command (a variation on the generate command – egen is covered in detail in a separate handout) to create the new id variable, making the new variable equal to the concatenation of the two variables initials and idnumber, like this:
egen id = concat(initials idstring)
Now use the list command to assure that the concatenation worked correctly: 

list id idstring initials idnumber

     +-----------------------------------------+

     |     id   idstring   initials   idnumber |

     |-----------------------------------------|

  1. | ER2033       2033         ER       2033 |

  2. | MP2012       2012         MP       2012 |

  3. | MA3017       3017         MA       3017 |

  4. | TA1002       1002         TA       1002 |

  5. | MR3087       3087         MR       3087 |

     |-----------------------------------------|

  6. | FT3069       3069         FT       3069 |

  7. | EA1028       1028         EA       1028 |

     +-----------------------------------------+

It worked.
Using split and destring to convert “120/80” to 120 and 80 (etc)
Now we’ll cover an example where we want to do essentially the opposite – split a string variable, and then convert the pieces into numeric variables.  We’ll use the case of blood pressure, recorded in the standard format with a slash between the systolic and diastolic numbers, e.g. “120/80”.  We want to be able to analyze the systolic and diastolic blood pressure measurements as numbers. You can use the split and destring commands to get what you need.
The split command tell Stata to separate, or “parse”, the variable into 2 parts, the part before and the part after a character that you specify.  In this case, we would parse the blood pressure variable using the “/” character.  For example, if your blood pressure string variable is called bpstring: 
split bpstring, parse(/)

Stata has created 2 new string variables, in this case bpstring1 and bpstring2, which are the systolic BP and diastolic BP, respectively.  Note the automatic and convenient naming convention!
Next, you’ll destring the variables so that you can run numeric analyses on them.  In this example, the variables are “clean”, containing only numerals, so you only need a simple destring command.  Just like with the tostring command, we’ll use the generate option to create new variables:

destring bpstring1, generate(sbp)

destring bpstring2, generate(dbp)

Finally, you can check to assure accurate conversion by listing both the original string variables with your new SBP and DBP variables.  You can use a table command for this. For example:
table bpstring, content(mean sbp mean dbp)

----------------------------------

 bpstring |  mean(sbp)   mean(dbp)

----------+-----------------------

  122/079 |        122          79

  138/079 |        138          79

  140/088 |        140          88

  145/082 |        145          82

  155/099 |        155          99

  160/088 |        160          88

  183/099 |        183          99

----------------------------------

Using force and ignore with destring
When a variable is mostly numeric but has some extra non-numeral characters, the destring command will need some additional help/clarifications to make it work.  There are two destring options that can be useful: force and ignore. 
Let’s say that in the blood pressure dataset, there is a variable indicating the number of blood pressure medications the patient reports taking, called bpmed.

list bpmed

     +-------+

     | bpmed |

     |-------|

  1. |     1 |

  2. |     2 |

  3. |     0 |

  4. |     ? |

  5. |     1 |

     |-------|

  6. |    >4 |

  7. |     3 |

     +-------+

Unfortunately, the research assistant has entered a “?” when the patient did not know if they were taking a medication or the number was not available instead of leaving it blank. Having this character in the variable list makes Stata treat this as a string variable, not a numeric one, when you import the data.  But you want to use these numbers in your analysis.  You can use the force command to convert observations containing nonnumeric characters into missing values and then destring the variable into a numeric variable. 

In addition, there are some entries of the bpmed variable that are “>4,” since 4 was the maximum response allowed on the survey.  In the case of categorical data with extra non-numeric characters (in this case, the “>” sign), the goal is to drop the non-numeric character and just use the numeric portion of that observation. You can do this using the ignore command, which tells Stata to ignore specified non-numeric characters.  
The following command tells Stata to ignore the “>” sign, to replace the remaining values containing non-numeric characters (in this case, the “?s”) with a missing value, and to generate a new variable called bpmednew:
destring bpmed, ignore(>) force generate(bpmednew)
Stata then gives this output to report what changes have been made:
bpmed contains nonnumeric characters; bpmednew generated as byte

bpmed: characters > removed; bpmednew generated as byte

(1 missing value generated)

The list command below shows that it worked. 
list bpmednew bpmed

     +------------------+

     | bpmednew   bpmed |

     |------------------|

  1. |        1       1 |

  2. |        2       2 |

  3. |        0       0 |

  4. |        .       ? |

  5. |        1       1 |

     |------------------|

  6. |        4      >4 |

  7. |        3       3 |

     +------------------+

