*cd "/Users/dave/UCSF/Projects/Teaching/Teaching 18/Lecture 5/"
use "lecture5-1.dta", clear

capture log using lecture5-two.log, replace

set more off


* Slide 7
reg  cold_isc txtype death  i.hlam age_don age 
gen id = _n
/*

	Fitting a conventional multiple imputation

*/
* Slide 21
mi set mlong
mi register imputed cold_isc
mi register regular death hlamat age_don age 
* slide 24/25
mi impute regress cold_isc = death txtype i.hlamat age_don age, add(100) rseed(123) dots

* Slide 8 -- the histogram
hist cold_isc if _mi_m > 0 & txtype==0 & hlamat==3, scheme(s1color)
graph export "hist1.pdf", as(pdf) replace
summ cold_isc if _mi_m > 0 & txtype==0 & hlamat==3

* Slide 11 -- Imputation by PMM
capture mi extract 0, clear
mi set mlong
mi register imputed cold_isc
mi register regular death hlamat age_don age 
* slide 26
mi impute pmm cold_isc = hlamat age_don age death  prevtx txtype , add(100) rseed(123) dots knn(1)
hist cold_isc if _mi_m > 0 & txtype==0 & hlamat==3, scheme(s1color)
graph export "hist2.pdf", as(pdf) replace

* Slide 12
summ cold_isc if _mi_m > 0 &  txtype==0 & hlamat==3

* slide 27
tabulate _mi_m if _mi_m <= 20

use "lecture5-2.dta", clear

* Slide 28
mi set mlong
mi register imputed hlamat age_don age cold_isc prevtx txtype 
* Slide 29/30
mi impute chained (regress) cold_isc (ologit) hlamat (regress) age_don ///
 (regress) age (logit) prevtx =  death txtype, add(5) rseed(897)
 
* Slide 34
mi xeq 1: logistic death cold_isc age_don age  prevtx txtype i.hlamat
* Slide 38
mi estimate, eform: logistic death cold_isc age_don age  prevtx txtype i.hlamat

use "lecture5-2.dta", clear
mi set mlong
mi register imputed hlamat age_don age cold_isc prevtx txtype
mi impute chained (pmm, knn(1)) cold_isc (ologit) hlamat (regress) age_don ///
 (regress) age (logit) prevtx =  death txtype, add(5) rseed(897) replace dots
 

use "lecture5-2.dta", clear
mi set mlong
mi register imputed hlamat age_don age cold_isc prevtx txtype 
* Slide 46: 
mi impute chained (pmm, knn(1)) cold_isc (ologit) hlamat (regress) age_don ///
 (regress) age (logit) prevtx =  death txtype, add(50) rseed(897) replace dots
mi estimate, eform: logistic death cold_isc age_don age  prevtx txtype i.hlamat

* Slide 42
mi xeq 10: summ cold_isc
* Slide 43
mi xeq 10: logistic death cold_isc age_don age  prevtx txtype i.hlamat
 
* Slide 41 
preserve
mi extract 10, clear
logistic death cold_isc age_don age  prevtx txtype i.hlamat
restore

use "lecture5-2.dta", clear
mi set mlong
mi register imputed hlamat age_don age cold_isc prevtx txtype 
* Slide 47 
mi impute chained (pmm, knn(1)) cold_isc (ologit) hlamat (regress) age_don ///
 (regress) age (logit) prevtx =  death txtype, add(500) rseed(897) replace dots
mi estimate, eform: logistic death cold_isc age_don age  prevtx txtype i.hlamat

log close