cd "~/Documents/teaching/c2014/biostat208/labs/lab5"

capture log close
log using lab5, replace
use lab5, clear

* interaction of treatment and statin use on year 1 LDL

gen ldlch = ldl1-ldl0
table ht statins, contents(mean ldlch)
reg ldlch i.ht##i.statins
* effect of HT in non-users
lincom 1.ht
* effect of HT in statin users
lincom 1.ht + 1.ht#1.statins
* effect of statins in placebo
lincom 1.statins
* effect of statins in HT
lincom 1.statins + 1.ht#1.statins

* interaction of glucose metabolism group and BMI

recode glucose min/99 = 1 100/125=2 126/max = 3, gen(dmgrp)
replace dmgrp = 3 if diabetes==1
label define dmgrpvals 1 "normal" 2 "IFG" 3 "diabetes"
label values dmgrp dmgrpvals
* center BMI
gen cbmi = bmi-28.6
reg sbp i.dmgrp##c.cbmi
* overall 2-df test for interaction
testparm dmgrp#c.cbmi
* effects of 5-unit increase in BMI in the normal, IFG, and DM groups
lincom 5*cbmi
lincom 5*(cbmi+2.dmgrp#c.cbmi)
lincom 5*(cbmi+3.dmgrp#c.cbmi)
* between group contrasts by BMI level
lincom 3.dmgrp - 2.dmgrp + 1.4*(3.dmgrp#c.cbmi - 2.dmgrp#c.cbmi)

* interaction of BMI and glucose in model for SBP
gen cglucose = glucose-100
reg sbp age i.raceth c.cbmi##c.cglucose
* effect of 5-unit increase in BMI at selected glucose values
foreach g of numlist 80 90 100 125 {
	di _newline as result ///
		"Effect of a 5-unit increase in BMI on SBP when glucose = `g'"
	lincom 5*(c.cbmi + (`g'-100)*c.cbmi#c.cglucose)
	}
* effect of 10-unit increase in glucose at selected BMI values
foreach b of numlist 18.5 25 28.6 30 35 {
	di _newline as result ///
		"Effect of a 10-unit increase in glucose on SBP when BMI = `b'"
	lincom 10*(c.cglucose + (`b'-28.6)*c.cbmi#c.cglucose)
	}
	
log close