
Dealing with date variables in Stata

This handout talks you through:

1. Creating new (clean) date variables from your old (dirty) date variable using the “date” function

2. Formatting the new date variable so it displays in a way that you can read it as a date

3. Ways to use Stata’s special date functions to analyze date variables

How Stata deals with dates

When you transfer a column of dates from a flat file (such as Excel), STATA reads that date data as just a string of text, and does not automatically recognize it as a date or allow you do to anything special with it.  If your data come from an Excel file, it sometimes helps to have the date cells formatted with a 4 digit year (e.g. MM/DD/YYYY) as sometimes this makes it easier to format in STATA afterward.

 The way Stata deals with dates is to create an INTEGER that represents days elapsed from Jan 1, 1960 (an arbitrary fixed point in time) until the date specified.  So Jan 2, 1960 is represented by the number “1”, and Jan 1, 1961 by the number “365”.  

Generating Stata integer dates from string dates

In order to generate these integers, use the date function.  Here’s the basic syntax:

date(yourdatestringvar, “format”)  

where format can be MDY (month/day/year, like 12/7/1996) or DMY (24/6/1980) or MD19Y (if you have a 2-digit year that always refers to 19xx) or MD20Y (always in 2000) or other formats.  If you have both 19xx and 20xx 2 digit years, you need to tell Stata what year “cutoff” to use, beyond which it assumes 19xx and before which it assumes 20xx.  
The date function is used to generate a new STATA-recognized date variable.  Here’s an example:

Lets say you have a string variable named “bday” that has dates written in the format of month, day, year (ex: 07/01/07).

     +----------+

     |     bday |

     |----------|

  1. | 01/03/60 |

  2. | 03/22/01 |

  3. | 08/18/04 |

  4. | 10/12/74 |

     +----------+
To create a new, “clean” version of the date variable, use this command:

generate bdaynew=date(bday,"MDY", 2010)

This turns the date into an integer representing the number of days elapsed between Jan 1, 1960 and the given date.

     +--------------------+

     |     bday   bdaynew |

     |--------------------|

  1. | 01/03/60         2 |

  2. | 03/22/01     15056 |

  3. | 08/18/04     16301 |

  4. | 10/12/74      5398 |

     +--------------------+
Displaying Stata’s integer dates so we can interpret them

Once the date is in the form of an integer, it is hard for a human to read it and know what the actual date is without some fancy calculations.  Stata does these for you, and can DISPLAY the values of the date variable as a readable date string.  Note that this is only a display/label function, and does not change the actual underlying integer values at all.  Here’s the syntax:

format newdatevariablename %td 

and here’s an example:

format bdaynew %td

     +----------------------+

     |     bday     bdaynew |

     |----------------------|

  1. | 01/03/60   03jan1960 |

  2. | 03/22/01   22mar2001 |

  3. | 08/18/04   18aug2004 |

  4. | 10/12/74   12oct1974 |

     +----------------------+
The values displayed here (in the browser/editor or using a tabulate command, for example) are now interpretable as the actual dates, though the underlying values of the variable are still integers.  

Analyzing Stata integer dates

You can do any sort of mathematical manipulation of this integer variable, like this:

gen bday10 = bdaynew + 10

     +-------------------------------+

     |     bday     bdaynew   bday10 |

     |-------------------------------|

  1. | 01/03/60   03jan1960       12 |

  2. | 03/22/01   22mar2001    15066 |

  3. | 08/18/04   18aug2004    16311 |

  4. | 10/12/74   12oct1974     5408 |

     +-------------------------------+
Which you then could format as a date with format bday10 %td
     +----------------------------------+

     |     bday     bdaynew      bday10 |

     |----------------------------------|

  1. | 01/03/60   03jan1960   13jan1960 |

  2. | 03/22/01   22mar2001   01apr2001 |

  3. | 08/18/04   18aug2004   28aug2004 |

  4. | 10/12/74   12oct1974   22oct1974 |

     +----------------------------------+
And it is easy to get time elapsed, in days, by just subtracting: gen daysdiff = bday10 - bdaynew
     +---------------------------------------------+

     |     bday     bdaynew      bday10   daysdiff |

     |---------------------------------------------|

  1. | 01/03/60   03jan1960   13jan1960         10 |

  2. | 03/22/01   22mar2001   01apr2001         10 |

  3. | 08/18/04   18aug2004   28aug2004         10 |

  4. | 10/12/74   12oct1974   22oct1974         10 |

     +---------------------------------------------+

You can also use special date functions provided by Stata – here are some examples:

Comparing to another date:  You can use normal mathematical operands to work with STATA formatted dates (<, >, = , etc.)  However, if you want to compare a date variable to a certain (specific) date you have to specify this to STATA. You can impute a literal date by putting a “d” in front of it and putting the date in parenthesis.


Generate bornafter1940 = 0

Replace bornafter1940 = 1 if bdaynew > d(1jan1940)
Extracting month, day, year:  You can get STATA to extract the specific day, month, or year from a correctly formatted STATA date variable.  For example, if you had everyone’s birthday (bdaynew) and wanted to select out all participants born before 1970 you could generate a “birthyear” variable and analyze it.   Here are the commands for generating a new variable using the day, day of week,  month, or year commands:

gen nameofdayvariable = day(datevariable)

gen nameofweekdayvariable = dow(datevariable)

gen nameofmonthvariable = month(datevariable)

gen nameofyearvariable = year(datevariable)
and here are some examples:
gen bdayday = day(bdaynew)

gen bdaydow = dow(bdaynew)

gen bdaymo = month(bdaynew)

gen bdayyr = year(bdaynew)
     +-------------------------------------------------+

     |   bdaynew   bdayday   bdaydow   bdaymo   bdayyr |

     |-------------------------------------------------|

  1. | 03jan1960         3         0        1     1960 |

  2. | 22mar2001        22         4        3     2001 |

  3. | 18aug2004        18         3        8     2004 |

  4. | 12oct1974        12         6       10     1974 |

     +-------------------------------------------------+

See Statas help menu (help dates) for more functions and more information about using dates.

Do File Example – Paste text below into a do file and run it to see these data commands in action.

clear

* Input 4 dates

gen str8 bday = ""

input

"01/03/60"

"03/22/01"

"08/18/04"

"10/12/74"

end

list

* How to create a new STATA variable called bdaynew from an old unrecognized date var bday *

gen bdaynew = date(bday, "MDY", 2010)

list

* How to label bdaynew as a day month and year so you can understand it*

format bdaynew %td

list

*Manipulating dates:  adding, subtracting, extracting components*

gen bday10 = bdaynew + 10

list

format bday10 %td

list

gen daysdiff = bday10 - bdaynew

list

gen bdayday = day(bdaynew)

gen bdaydow = dow(bdaynew)

gen bdaymo = month(bdaynew)

gen bdayyr = year(bdaynew)

list bdaynew bdayday bdaydow bdaymo bdayyr


