
How to Program A “Loop” with Stata

When you have a repetitive task, using a loop helps cut down on your programming work and helps you avoid programming errors.  You’ll get an introduction to loops in Lecture 6.  This handout goes into a bit more detail, providing examples of using loops for creating new variables, cleaning variables and analyzing variables.

Basic concept

When you program a loop, you have to tell Stata 3 basic things:

1) What you want to do repetitively

2) How many times you want to do it

3) What changes each time

Here’s an example of a basic loop (you can paste this into a do file and run it):

forvalues x = 1/5 {

display "`x' + 1 = " 

display `x' + 1

display ""

}

Regarding the basic tasks above:

1) All the commands between { and } are the commands done repetitively

2) The forvalues command tells Stata you want to do the loop 5 times, one for each value between 1 and 5, inclusive

3) The forvalues command also designates “x” as the placeholder for the thing that will change, and then anywhere that `x' appears in the commands in the brackets, Stata substitutes the actual value (1, 2, 3, 4 or 5) corresponding with that run of the loop.

Other important quirks and notes about the syntax:

· The open brace must appear on the same line as foreach
· Nothing may follow the open brace except comments; the first command to be executed must appear on a new line
· The “  ` ” symbol is the quote right below the ~ on your keyboard and the “  ' ” symbol is the quote below the “ on your keyboard. 

· The close brace must appear on a line by itself

For more advice about using forvalues, and also foreach (another way of setting up a loop when you have a list of things you want to loop through instead of a set of numbers), look up forvalues and foreach in Stata’s help menu.  A couple of quick notes on forvalues:
· You can specify min/max to indicate a sequence of numbers. For example 1/3 yields 1, 2 and 3
· You can specify first(step)last to indicate a sequence that skips numbers.  For example 15(5)50 yields 15,20,25,30,35,40,45 and 50. 

Below are some examples of how to use loops.

Example 1: Creating New Variables
Say you have a dataset in which weight (in lbs) and height (in inches) have been measured monthly. However, you need to recalculate the weight (change from lbs to kg) and the height (change from inches to meters), so that you can analyze monthly BMI.

Consider the dataset listing monthly weights (in lbs) for 3 individuals:

	id
	wt1
	wt2
	wt3
	wt4
	wt5
	wt6
	wt7
	wt8
	wt9
	wt10
	wt11
	wt12

	1
	160
	154
	153
	155
	160
	163
	163
	165
	166
	168
	169
	168

	2
	120
	122
	120
	121
	125
	127
	126
	126
	125
	122
	123
	124

	3
	143
	144
	144
	145
	147
	149
	150
	151
	152
	152
	153
	154


Manually, we can convert weight in lbs to kg by the following generate commands:

generate kgwt1 = wt1/2.2

generate kgwt2 = wt2/2.2

generate kgwt3 = wt3/2.2

generate kgwt4 = wt4/2.2

generate kgwt5 = wt5/2.2

generate kgwt6 = wt6/2.2

generate kgwt7 = wt7/2.2

generate kgwt8 = wt8/2.2

generate kgwt9 = wt9/2.2

generate kgwt10 = wt10/2.2

generate kgwt11 = wt11/2.2

generate kgwt12 = wt12/2.2

or, we could use a foreach loop to do this task, like so:

foreach var of varlist wt1-wt12 {

generate kg`var' = `var'/2.2

}

Note that we’ve used the foreach command here, and can specify a list of variables (a varlist) that are named similarly with numbers as noted above (see help varlist for more details).  Stata will cycle through wt1, wt2, …wt12, substituting the names of that variable wherever `var' appears in the bracketed commands.
We could write a loop to do the same for converting height to meters and then for calculating BMI, or we could put all those commands into a single loop, as below:

forvalues x = 1/12 {

generate kgwt`x' = wt`x'/2.2

generate mht`x'  = ht`x' * 2.54/100

generate bmi`x'  = kgwt`x'/(mht`x'^2) 

}

For this one, note that we’ve used the forvalues command.  For ANOTHER interesting way to solve this problem, consider reshaping the data from wide to long and then doing the analysis (see the Reshape Handout).  Many ways to skin the cat…

Example 2: Data Cleaning and Dummy Variables
Loops can help with cleaning variables or creating “dummy” variables.  Say you are given a variable of age, but want to want to specifically identify those people ages 25, 26, 27, 28, and 29 years old. The following loop command may be used:

forvalues x=25/29 { 

gen age`x'=0

replace age`x'=1 if age==`x' 

} 

This loop uses the min/max format to generate 5 new dummy variables: age25, age26, age27, age28 and age29 – all variables are set to = 0. The replace command on the next line then replaces the 5 newly generated variables with the value “1” if that individual is equal to the age in that specific label. 

You can also create dummy variables to represent age groups by five-year intervals using the first(step)last format: 

forvalues bottom = 20(5)45 {
local top = `bottom' + 4 

gen age`bottom'to`top' = 0

replace age`bottom'to`top' = 1 if age >= `bottom' & age <= `top' 

} 

This creates 6 new dummy variables: age20to24 to age45to49.  The way the loop works is that the local variable bottom will take values between 20 and 45 in steps of 5 (hence 20, 25, 30, 35, 40, and 45), the lower bounds of the age groups. 

Inside the loop we create a local macro top to represent the upper bounds of the age groups, which equals the lower bound plus 4. The first time through the loop bottom is 20, so top is 24.  We use an equal sign to store the result of adding 4 to bottom. 

The next line is a simple generate statement. The first time through the loop the line will say gen age20to24 = 0, and then the replace statement will set it equal to 1 if age >= 20 & age <= 24.  This will create the first dummy variable age20to24. Then Stata will go back to the top to create the next one. Here is the newly created dataset, with the new five-year interval categories.

	Id
	Age
	Age20to24
	Age25to29
	Age30to34
	Age35to39
	Age40to44
	Age45to49

	1
	25
	0
	1
	0
	0
	0
	0

	2
	30
	0
	0
	1
	0
	0
	0

	3
	35
	0
	0
	0
	1
	0
	0

	4
	41
	0
	0
	0
	0
	1
	0

	5
	42
	0
	0
	0
	0
	1
	0

	6
	41
	0
	0
	0
	0
	1
	0

	7
	25
	0
	1
	0
	0
	0
	0

	8
	37
	0
	0
	0
	1
	0
	0

	9
	44
	0
	0
	0
	0
	1
	0

	10
	21
	1
	0
	0
	0
	0
	0


Example 3: Analyzing Variables 
Let’s return to our beloved “Coronary Calcium.dta” for a final example using loops to analyze data.  Say we want to know if gender is related to co-morbidities (hypertension, diabetes, smoking). These are categorical variables, so the manual set up is:

tabulate male htn, col chi2

tabulate male dm, col chi2

tabulate male smoke, col chi2

Alternatively, we can use the foreach command to loop our data, performing the same tabulate command with a simple Chi-squared test of significance on several variables all in one step. See the following command with its associated output:

[image: image1.png]. foreach x in htn dm smoke {
2. tab male “x', col chi2

3.}

Key

frequency
column percentage

htn
male ) 1 Total
0 2,242 1,947 4,189
38.31 43.08 40.39
1 3,610 2,573 6,183
61.69 56.92 59.61
Total 5,852 4,520 10,372
100.00 100.00 100.00
Pearson chi2(1) = 24.0355 Pr = 0.000
Key
frequency
column percentage
dm
male ) 1 Total
0 3,801 388 4,189
40.15 43.02 40.40
1 5,667 514 6,181
59.85 56.98 59.60
Total 9,468 902 10,370
100.00 100.00 100.00
Pearson chi2(1) = 2.8169 Pr = 0.093
Key
frequency
column percentage
smoke
male ) 1 Total
0 2,723 1,466 4,189
43.48 35.67 40.39
1 3,539 2,644 6,183
56.52 64.33 59.61
Total 6,262 4,110 10,372
100.00 100.00 100.00
Pearson chi2(1) = 62.9523 Pr = 0.000





